;;; TORVA LISP - Opening X Mark (torva.kr/lisp.html)
;;; XX  : two corners -> X inside, layer OPEN
;;; XXX : same + rectangle border
;;; Layer OPEN is created if missing (color 1). No settings.

(vl-load-com)

(setq *TV-XM-LAYER* "OPEN")

(defun tv-xm-layer ()
  (if (null (tblsearch "LAYER" *TV-XM-LAYER*))
    (entmake (list '(0 . "LAYER") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLayerTableRecord")
                   (cons 2 *TV-XM-LAYER*) '(70 . 0) '(62 . 1) '(6 . "Continuous")))))

(defun tv-xm-pt (x y) (list x y 0.0))

(defun tv-xm-line (a b)
  (entmakex (list '(0 . "LINE") '(100 . "AcDbEntity") (cons 8 *TV-XM-LAYER*) '(100 . "AcDbLine") (cons 10 a) (cons 11 b))))

;; pick two corners, draw X (+ border if box). returns the corners or nil
(defun tv-xm-draw (box / p1 p3 p2 p4)
  (setq p1 (getpoint "\nù ±¸¼®: "))
  (if p1 (setq p3 (getcorner p1 "\n¹Ý´ë ±¸¼®: ")))
  (if (and p1 p3)
    (progn
      (tv-xm-layer)
      (setq p1 (tv-xm-pt (car p1) (cadr p1)) p3 (tv-xm-pt (car p3) (cadr p3))
            p2 (tv-xm-pt (car p1) (cadr p3)) p4 (tv-xm-pt (car p3) (cadr p1)))
      (tv-xm-line p1 p3) (tv-xm-line p2 p4)
      (if box
        (entmakex (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") (cons 8 *TV-XM-LAYER*) '(100 . "AcDbPolyline")
                        '(90 . 4) '(70 . 1) (cons 10 p1) (cons 10 p2) (cons 10 p3) (cons 10 p4))))
      (list p1 p3))))

(defun tv-xm-err (msg)
  (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
  (princ))

(defun c:XX (/ *error* old)
  (setq old *error* *error* tv-xm-err)
  (if (tv-xm-draw nil) (princ "\nX mark drawn (layer OPEN)"))
  (setq *error* old)
  (princ))

(defun c:XXX (/ *error* old)
  (setq old *error* *error* tv-xm-err)
  (if (tv-xm-draw T) (princ "\nX mark + border drawn (layer OPEN)"))
  (setq *error* old)
  (princ))

(princ "\nTORVA X Mark: XX / XXX | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----