;;; TORVA LISP - Wall Draw (torva.kr/lisp.html)
;;; WLD : start point, end point, then move the cursor to the side the wall goes and click
;;;       -> closed rectangle wall (the two points are one face, thickness goes to the cursor side). Repeats until Enter
;;; Type a number at the start prompt to change the thickness (default 200, kept until the drawing closes)
;;; Thickness is in drawing units. Right click or a key during the side pick skips that wall
;;; Layer WALL (color 2), created if missing. Works in any UCS. U undoes one whole WLD run

(vl-load-com)

(if (null *TV-WLD-W*) (setq *TV-WLD-W* 200.0))

;; number for prompts: 2 decimals below 10 (m drawings), else whole
(defun tv-wld-n (v) (rtos v 2 (if (< (abs v) 10) 2 0)))

;; four UCS corners: face p1-p2, thickness to the side of cursor point c
(defun tv-wld-pts (p1 p2 c / a d)
  (setq a (angle p1 p2)
        d (if (> (sin (- (angle p1 c) a)) 0) (/ pi 2.0) (/ pi -2.0)))
  (list p1 p2 (polar p2 (+ a d) *TV-WLD-W*) (polar p1 (+ a d) *TV-WLD-W*)))

;; closed LWPOLYLINE from UCS points, in the OCS of the UCS normal
(defun tv-wld-make (pts / nrm)
  (setq nrm (trans '(0.0 0.0 1.0) 1 0 T))
  (entmakex (append (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") '(8 . "WALL") '(100 . "AcDbPolyline")
                          '(90 . 4) '(70 . 1) (cons 38 (caddr (trans (car pts) 1 nrm))))
                    (mapcar '(lambda (p / o) (setq o (trans p 1 nrm)) (list 10 (car o) (cadr o))) pts)
                    (list (cons 210 nrm)))))

;; live preview while the cursor moves; click = corners, right click / key = nil
(defun tv-wld-side (p1 p2 / gr pts done)
  (princ "\nº® ¹æÇâ Ŭ¸¯: ")
  (while (not done)
    (setq gr (grread T 15 0))
    (cond
      ((member (car gr) '(3 5))
       (redraw)
       (setq pts (tv-wld-pts p1 p2 (cadr gr)))
       (mapcar '(lambda (a b) (grdraw a b 1 1)) pts (append (cdr pts) (list (car pts))))
       (if (= (car gr) 3) (setq done T)))
      ((member (car gr) '(2 11 25)) (setq pts nil done T))))
  (redraw)
  pts)

(defun c:WLD (/ *error* old doc in v p1 p2 pts n loop)
  (setq old *error* doc (vla-get-ActiveDocument (vlax-get-acad-object)) n 0)
  (defun *error* (msg)
    (redraw) (vla-EndUndoMark doc) (setq *error* old)
    (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*EXIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
    (princ))
  (vla-StartUndoMark doc)
  (if (null (tblsearch "LAYER" "WALL"))
    (entmake (list '(0 . "LAYER") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLayerTableRecord")
                   '(2 . "WALL") '(70 . 0) '(62 . 2) '(6 . "Continuous"))))
  (setq loop T)
  (while loop
    (initget 128)
    (setq in (getpoint (strcat "\nº® ½ÃÀÛÁ¡ ¶Ç´Â µÎ²² <" (tv-wld-n *TV-WLD-W*) ">: ")))
    (cond
      ((null in) (setq loop nil))
      ((= (type in) 'STR)
       (if (and (setq v (distof in)) (> v 0))
         (setq *TV-WLD-W* v)
         (princ "\nThickness must be a positive number")))
      ((and (setq p1 in) (setq p2 (getpoint p1 "\n³¡Á¡: ")) (setq pts (tv-wld-side p1 p2)))
       (tv-wld-make pts)
       (setq n (1+ n))
       (princ (strcat "\nWall " (tv-wld-n *TV-WLD-W*) " x " (tv-wld-n (distance p1 p2)))))))
  (princ (strcat "\nDone: " (itoa n) " walls"))
  (vla-EndUndoMark doc) (setq *error* old)
  (princ))

(princ "\nTORVA Wall Draw: WLD | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----