;;; TORVA LISP - Superscript / Subscript (torva.kr/lisp.html)
;;; SUP : pick a text -> type -> added at the end as superscript (m -> m2 raised)
;;; SUB : pick a text -> type -> added at the end as subscript
;;; Single-line TEXT is converted to MTEXT first (TXT2MTXT). Style and layer stay as they were

(vl-load-com)

;; body; fmt = "\\S~^;" for superscript, "\\S^~;" for subscript (~ = typed text)
(defun tv-script-run (fmt msg / *error* old doc ce sel ent obj s)
  (setq doc (vla-get-activedocument (vlax-get-acad-object))
        ce (getvar "CMDECHO") old *error*)
  (defun *error* (m)
    (setvar "CMDECHO" ce) (vla-EndUndoMark doc)
    (setq *error* old)
    (if (not (wcmatch (strcase m) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " m)))
    (princ))
  (vla-StartUndoMark doc)
  (if (setq sel (entsel "\n±ÛÀÚ ¼±ÅÃ: "))
    (progn
      (setq ent (car sel))
      (if (= (cdr (assoc 0 (entget ent))) "TEXT")
        (progn (setvar "CMDECHO" 0)
               (command "_.TXT2MTXT" ent "")
               (setq ent (entlast))
               (setvar "CMDECHO" ce)))
      (if (= (cdr (assoc 0 (entget ent))) "MTEXT")
        (if (/= (setq s (getstring T (strcat "\n" msg ": "))) "")
          (progn
            (setq obj (vlax-ename->vla-object ent))
            (vla-put-TextString obj (strcat (vla-get-TextString obj) "{"
                                            (vl-string-subst s "~" fmt) "}"))
            (princ (strcat "\nAdded: " s))))
        (princ "\nNot a text"))))
  (vla-EndUndoMark doc)
  (setq *error* old)
  (princ)
)

(defun c:SUP () (tv-script-run "\\S~^;" "À­Ã·ÀÚ"))
(defun c:SUB () (tv-script-run "\\S^~;" "¾Æ·¡Ã·ÀÚ"))

(princ "\nTORVA Superscript / Subscript: SUP / SUB | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----