;;; TORVA LISP - Text Match (torva.kr/lisp.html)
;;; TXM : pick a source (TEXT, MTEXT, DIMENSION, MULTILEADER) -> select targets -> every target gets the source content
;;; Targets: TEXT / MTEXT / MULTILEADER take the string, DIMENSION takes it as a text override
;;; A dimension source without override gives its measured value (dimension precision, scale factor, degrees for angular)
;;; Locked layers are skipped. One U undoes the command

(vl-load-com)

;; property or default when the object does not have it
(defun tv-tm-prop (o f d / r)
  (setq r (vl-catch-all-apply f (list o)))
  (if (vl-catch-all-error-p r) d r))

;; displayed content of the source object, nil if it has none
(defun tv-tm-source (o / s m)
  (if (wcmatch (vla-get-ObjectName o) "*Dimension*")
    (progn
      (setq s (vla-get-TextOverride o))
      (if (and (/= s "") (/= s "<>"))
        s
        (progn
          (setq m (vla-get-Measurement o))
          (if (wcmatch (vla-get-ObjectName o) "*Angular*")
            (strcat (angtos m 0 (tv-tm-prop o 'vla-get-TextPrecision 0)) "%%d")
            (rtos (* m (tv-tm-prop o 'vla-get-LinearScaleFactor 1.0)) 2 (tv-tm-prop o 'vla-get-PrimaryUnitsPrecision 2))))))
    (tv-tm-prop o 'vla-get-TextString nil)))

(defun c:TXM (/ *error* old doc flt ss src o i n skip r d)
  (setq old *error* doc (vla-get-ActiveDocument (vlax-get-acad-object))
        flt '((0 . "TEXT,MTEXT,DIMENSION,MULTILEADER")))
  (defun *error* (msg)
    (vla-EndUndoMark doc)
    (setq *error* old)
    (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
    (princ))
  (vla-StartUndoMark doc)
  (prompt "\n¿øº» ±ÛÀÚ ¼±ÅÃ: ")
  (if (setq ss (ssget "_:S" flt))
    (if (/= "" (setq src (cond ((tv-tm-source (vlax-ename->vla-object (ssname ss 0)))) (""))))
      (progn
        (princ (strcat "\nSource: \"" src "\""))
        (prompt "\n¹Ù²Ü ±ÛÀÚ¡¤Ä¡¼ö ¼±ÅÃ: ")
        (if (setq ss (ssget flt))
          (progn
            (setq i 0 n 0 skip 0)
            (repeat (sslength ss)
              (setq o (vlax-ename->vla-object (ssname ss i)) i (1+ i)
                    d (tblsearch "LAYER" (vla-get-Layer o)))
              (if (= 4 (logand 4 (cdr (assoc 70 d))))
                (setq skip (1+ skip))
                (progn
                  (setq r (vl-catch-all-apply
                            (if (wcmatch (vla-get-ObjectName o) "*Dimension*") 'vla-put-TextOverride 'vla-put-TextString)
                            (list o src)))
                  (if (not (vl-catch-all-error-p r)) (setq n (1+ n))))))
            (if (> skip 0) (princ (strcat "\nLocked layer, skipped " (itoa skip))))
            (princ (strcat "\n" (itoa n) " objects changed")))))
      (princ "\nNo text in the source")))
  (vla-EndUndoMark doc)
  (setq *error* old)
  (princ))

(princ "\nTORVA Text Match: TXM | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----