;;; TORVA LISP - Slab Name (torva.kr/lisp.html)
;;; SN : pick a point, type a name -> name text in an ellipse with a stepped underline
;;; H at the name prompt sets text height for this drawing session
;;; default height = 3.5 x DIMSCALE (350 at 1:100). ellipse and underline scale with height
;;; layer SLAB-NAME (created if missing). current text style

(vl-load-com)

(if (null *TV-SN-NAME*) (setq *TV-SN-NAME* "S1"))
(setq *TV-SN-LAYER* "SLAB-NAME")

(defun tv-sn-ds ()
  (if (> (getvar "DIMSCALE") 0) (getvar "DIMSCALE") 1.0))

;; text height - user value or drawing scale
(defun tv-sn-h ()
  (cond (*TV-SN-H*) ((* 3.5 (tv-sn-ds)))))

(defun tv-sn-layer ()
  (if (null (tblsearch "LAYER" *TV-SN-LAYER*))
    (entmake (list '(0 . "LAYER") '(100 . "AcDbSymbolTableRecord") '(100 . "AcDbLayerTableRecord")
                   (cons 2 *TV-SN-LAYER*) '(70 . 0) '(62 . 7) '(6 . "Continuous")))))

;; ask name - H changes height and asks again. Enter = default
(defun tv-sn-name (def / r v)
  (setq r "H")
  (while (= (strcase r) "H")
    (setq r (getstring (strcat "\n½½·¡ºê À̸§ [³ôÀÌ(H)] <" def ">: ")))
    (if (= (strcase r) "H")
      (if (setq v (getdist (strcat "\n±ÛÀÚ ³ôÀÌ <" (rtos (tv-sn-h) 2 0) ">: "))) (setq *TV-SN-H* v))))
  (if (= r "") def (strcase r)))

(defun tv-sn-text (pt h str)
  (entmakex (list '(0 . "TEXT") '(100 . "AcDbEntity") (cons 8 *TV-SN-LAYER*) '(100 . "AcDbText")
                  (cons 10 pt) (cons 11 pt) (cons 40 h) (cons 1 str) '(50 . 0.0)
                  (cons 7 (getvar "TEXTSTYLE")) '(72 . 1) '(73 . 2))))

;; ellipse - center, radius x, radius y
(defun tv-sn-ellipse (pt rx ry)
  (entmakex (list '(0 . "ELLIPSE") '(100 . "AcDbEntity") (cons 8 *TV-SN-LAYER*) '(100 . "AcDbEllipse")
                  (cons 10 pt) (cons 11 (list rx 0.0 0.0)) '(210 0.0 0.0 1.0)
                  (cons 40 (/ ry rx)) '(41 . 0.0) (cons 42 (* 2.0 pi)))))

(defun tv-sn-pline (pts)
  (entmakex (append (list '(0 . "LWPOLYLINE") '(100 . "AcDbEntity") (cons 8 *TV-SN-LAYER*) '(100 . "AcDbPolyline")
                          (cons 90 (length pts)) '(70 . 0))
                    (mapcar '(lambda (p) (cons 10 (list (car p) (cadr p)))) pts))))

(defun c:SN (/ *error* old ce pt name h u rx ry cx cy ly)
  (setq ce (getvar "CMDECHO") old *error*)
  (defun *error* (msg)
    (setvar "CMDECHO" ce) (setq *error* old)
    (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
    (princ))
  (setvar "CMDECHO" 0)
  (if (setq pt (getpoint "\n»ðÀÔÁ¡: "))
    (progn
      (setq name (tv-sn-name *TV-SN-NAME*) *TV-SN-NAME* name)
      (tv-sn-layer)
      (setq h (tv-sn-h) u (/ h 3.5)                       ; u = 100 when height is 350
            pt (list (car pt) (cadr pt) 0.0) cx (car pt) cy (cadr pt))
      ;; ellipse - ry 3.2u, rx 5.5u + 1.5u per character over 3
      (setq ry (* 3.2 u) rx (+ (* 5.5 u) (* 1.5 u (max 0 (- (strlen name) 3)))))
      (tv-sn-text pt h name)
      (tv-sn-ellipse pt rx ry)
      ;; underline - 3u below the ellipse, 11u wide, ends stepped 1.5u
      (setq ly (- cy ry (* 3.0 u)))
      (tv-sn-pline (list (list (- cx (* 3.0 u)) (+ ly (* 1.5 u))) (list (- cx (* 5.5 u)) ly)
                         (list (+ cx (* 5.5 u)) ly) (list (+ cx (* 3.0 u)) (- ly (* 1.5 u)))))
      (princ (strcat "\nSlab " name " placed"))))
  (setvar "CMDECHO" ce) (setq *error* old)
  (princ))

(princ "\nTORVA Slab Name: SN | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----