;;; TORVA LISP - Rotate Align (torva.kr/lisp.html)
;;; RAL : select objects (one pick or one window) -> pick a reference LINE or XLINE
;;;   -> the objects rotate in place by the reference angle (measured from the current UCS X axis)
;;;   pivot = center of the bounding box around all selected objects (xlines / rays left out of the box)
;;;   only xlines / rays selected -> pivot = the point picked on the reference
;;;   the angle is folded into -90..90 so text never ends upside down
;;; Rotation is about the Z axis (plan views). Objects on locked layers are skipped. One U undoes the whole run

(vl-load-com)

(defun c:RAL (/ *error* old doc ss es ed ang mn mx lo hi i en base n skip)
  (setq doc (vla-get-ActiveDocument (vlax-get-acad-object)) old *error*)
  (defun *error* (msg)
    (vla-EndUndoMark doc)
    (setq *error* old)
    (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
    (princ))
  (princ "\nȸÀüÇÒ °´Ã¼: ")
  (if (and (setq ss (ssget "_:S")) (setq es (entsel "\n±âÁؼ±: ")))
    (progn
      (setq ed (entget (car es)))
      (cond
        ((= (cdr (assoc 0 ed)) "LINE")
         (setq ang (angle (trans (cdr (assoc 10 ed)) 0 1) (trans (cdr (assoc 11 ed)) 0 1))))
        ((= (cdr (assoc 0 ed)) "XLINE")
         (setq ang (angle '(0 0 0) (trans (cdr (assoc 11 ed)) 0 1 T)))))
      (if (null ang)
        (princ "\nNot a line or xline")
        (progn
          (while (>= ang (/ pi 2)) (setq ang (- ang pi)))
          (while (< ang (/ pi -2)) (setq ang (+ ang pi)))
          (setq i 0)
          (repeat (sslength ss)
            (setq en (ssname ss i) i (1+ i))
            (if (and (not (wcmatch (cdr (assoc 0 (entget en))) "XLINE,RAY"))
                     (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-GetBoundingBox (list (vlax-ename->vla-object en) 'mn 'mx)))))
              (setq mn (vlax-safearray->list mn) mx (vlax-safearray->list mx)
                    lo (if lo (mapcar 'min lo mn) mn)
                    hi (if hi (mapcar 'max hi mx) mx))))
          (setq base (if lo (mapcar '(lambda (a b) (/ (+ a b) 2.0)) lo hi) (trans (cadr es) 1 0)))
          (vla-StartUndoMark doc)
          (setq i 0 n 0 skip 0)
          (repeat (sslength ss)
            (if (vl-catch-all-error-p
                  (vl-catch-all-apply 'vla-Rotate (list (vlax-ename->vla-object (ssname ss i)) (vlax-3d-point base) ang)))
              (setq skip (1+ skip))
              (setq n (1+ n)))
            (setq i (1+ i)))
          (vla-EndUndoMark doc)
          (princ (strcat "\n" (itoa n) " rotated by " (rtos (* ang (/ 180.0 pi)) 2 2) " deg"
                         (if (> skip 0) (strcat ", locked layer, skipped " (itoa skip)) "")))))))
  (setq *error* old)
  (princ)
)

(princ "\nTORVA Rotate Align: RAL | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----