;;; TORVA LISP - Point to Lines (torva.kr/lisp.html)
;;; PTS : select POINTs -> each is replaced by real lines / circle in the current point style (PDMODE):
;;;       + (2), X (3), tick (4), plus circle (+32) and square (+64). Dot styles (0, 1) become a small circle
;;; Size = PDSIZE, or for PDSIZE 0 / negative the size CAD shows on screen (5 % / n % of the view height)
;;; Layer and color of the point are kept. Points on locked layers are skipped. One U restores the points
;;; Use it before sending a drawing to another CAD or plotting, where the point style is lost

(vl-load-com)

(defun tv-pts-line (d p q)
  (entmake (append (list '(0 . "LINE")) d (list (cons 10 p) (cons 11 q)))))

(defun c:PTS (/ *error* old doc ss md pd sz h base i e ed lay d pt cx cy cz n skip)
  (setq old *error* doc (vla-get-ActiveDocument (vlax-get-acad-object)) n 0 skip 0)
  (defun *error* (msg)
    (vla-EndUndoMark doc)
    (setq *error* old)
    (if (and msg (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*"))) (princ (strcat "\nError: " msg)))
    (princ))
  (princ "\n선으로 바꿀 점 선택: ")
  (if (setq ss (ssget '((0 . "POINT"))))
    (progn
      (setq md (getvar "PDMODE") pd (getvar "PDSIZE")
            sz (cond ((> pd 0) pd)
                     ((< pd 0) (* (abs pd) 0.01 (getvar "VIEWSIZE")))
                     (T (* 0.05 (getvar "VIEWSIZE"))))
            h (/ sz 2.0) base (logand md 15) i 0)
      (vla-StartUndoMark doc)
      (repeat (sslength ss)
        (setq e (ssname ss i) i (1+ i) ed (entget e) lay (cdr (assoc 8 ed)))
        (if (= 4 (logand 4 (cdr (assoc 70 (tblsearch "LAYER" lay)))))
          (setq skip (1+ skip))
          (progn
            (setq d (vl-remove nil (list (cons 8 lay) (assoc 62 ed)))
                  pt (cdr (assoc 10 ed)) cx (car pt) cy (cadr pt) cz (caddr pt))
            (cond
              ((= base 2)
               (tv-pts-line d (list (- cx h) cy cz) (list (+ cx h) cy cz))
               (tv-pts-line d (list cx (- cy h) cz) (list cx (+ cy h) cz)))
              ((= base 3)
               (tv-pts-line d (list (- cx h) (- cy h) cz) (list (+ cx h) (+ cy h) cz))
               (tv-pts-line d (list (- cx h) (+ cy h) cz) (list (+ cx h) (- cy h) cz)))
              ((= base 4)
               (tv-pts-line d pt (list cx (+ cy h) cz))))
            (if (= 32 (logand md 32))
              (entmake (append (list '(0 . "CIRCLE")) d (list (cons 10 pt) (cons 40 h)))))
            (if (= 64 (logand md 64))
              (progn
                (tv-pts-line d (list (- cx h) (- cy h) cz) (list (+ cx h) (- cy h) cz))
                (tv-pts-line d (list (+ cx h) (- cy h) cz) (list (+ cx h) (+ cy h) cz))
                (tv-pts-line d (list (+ cx h) (+ cy h) cz) (list (- cx h) (+ cy h) cz))
                (tv-pts-line d (list (- cx h) (+ cy h) cz) (list (- cx h) (- cy h) cz))))
            (if (and (< base 2) (/= 32 (logand md 32)) (/= 64 (logand md 64)))
              (entmake (append (list '(0 . "CIRCLE")) d (list (cons 10 pt) (cons 40 (/ h 5.0))))))
            (entdel e)
            (setq n (1+ n)))))
      (vla-EndUndoMark doc)
      (princ (strcat "\n" (itoa n) " point(s) -> lines (PDMODE " (itoa md) ", size " (rtos sz 2 1) ")"
                     (if (> skip 0) (strcat ", locked layer, skipped " (itoa skip)) "")))))
  (setq *error* old)
  (princ)
)

(princ "\nTORVA Point to Lines: PTS | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "영문·숫자만")
    ((getcname key) "AutoCAD 명령 이름")
    ((tv-key-pgp-p key) "acad.pgp 별칭과 같음")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "이미 있는 리습 명령")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n단축키를 붙일 명령 [목록(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " 의 새 단축키 [지우기(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----
