;;; TORVA LISP - Layer Isolate (torva.kr/lisp.html)
;;; LYI : select objects -> only their layers (and the current layer) stay on, every other layer is turned off
;;; LYU : turns back on the layers LYI turned off (layers that were off before LYI stay off).
;;;       If LYI was not used since the drawing opened, LYU turns every layer on
;;; Layers are switched off, not locked or faded, so the drawing plots as shown. Frozen layers are not touched
;;; LYI twice in a row narrows further; one LYU brings back everything both turned off. U undoes each step

(vl-load-com)

(defun c:LYI (/ *error* old doc ss i nm keep n)
  (setq old *error* doc (vla-get-ActiveDocument (vlax-get-acad-object)) n 0)
  (defun *error* (msg)
    (vla-EndUndoMark doc)
    (setq *error* old)
    (if (and msg (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*"))) (princ (strcat "\nError: " msg)))
    (princ))
  (princ "\n남길 레이어의 객체 선택: ")
  (if (setq ss (ssget))
    (progn
      (setq keep (list (strcase (getvar "CLAYER"))) i 0)
      (repeat (sslength ss)
        (setq nm (strcase (cdr (assoc 8 (entget (ssname ss i))))) i (1+ i))
        (if (not (member nm keep)) (setq keep (cons nm keep))))
      (vla-StartUndoMark doc)
      (vlax-for lo (vla-get-Layers doc)
        (if (and (= (vla-get-LayerOn lo) :vlax-true) (not (member (strcase (vla-get-Name lo)) keep)))
          (progn
            (vla-put-LayerOn lo :vlax-false)
            (setq *TV-LYI-OFF* (cons (vla-get-Name lo) *TV-LYI-OFF*) n (1+ n)))))
      (vla-EndUndoMark doc)
      (princ (strcat "\n" (itoa (length keep)) " layer(s) kept, " (itoa n) " turned off | LYU = back on"))))
  (setq *error* old)
  (princ)
)

(defun c:LYU (/ *error* old doc lays lo n)
  (setq old *error* doc (vla-get-ActiveDocument (vlax-get-acad-object)) lays (vla-get-Layers doc) n 0)
  (defun *error* (msg)
    (vla-EndUndoMark doc)
    (setq *error* old)
    (if (and msg (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*"))) (princ (strcat "\nError: " msg)))
    (princ))
  (vla-StartUndoMark doc)
  (if *TV-LYI-OFF*
    (foreach nm *TV-LYI-OFF*
      (if (and (tblsearch "LAYER" nm) (setq lo (vla-Item lays nm)) (= (vla-get-LayerOn lo) :vlax-false))
        (progn (vla-put-LayerOn lo :vlax-true) (setq n (1+ n)))))
    (vlax-for lo lays
      (if (= (vla-get-LayerOn lo) :vlax-false)
        (progn (vla-put-LayerOn lo :vlax-true) (setq n (1+ n))))))
  (setq *TV-LYI-OFF* nil)
  (vla-EndUndoMark doc)
  (princ (strcat "\n" (itoa n) " layer(s) back on"))
  (setq *error* old)
  (princ)
)

(princ "\nTORVA Layer Isolate: LYI / LYU | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "영문·숫자만")
    ((getcname key) "AutoCAD 명령 이름")
    ((tv-key-pgp-p key) "acad.pgp 별칭과 같음")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "이미 있는 리습 명령")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n단축키를 붙일 명령 [목록(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " 의 새 단축키 [지우기(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----
