;;; TORVA LISP - Hatch Scale / Line Width (torva.kr/lisp.html)
;;; HSC : selected hatches -> one pattern scale (default = scale of the first hatch). Pre-selected hatches are used as is
;;; PLW : selected lines, arcs, polylines -> polylines with one global width (lines and arcs are converted)
;;; Width default = 5 x DIMSCALE (500 at 1:100), last value persists until the drawing closes
;;; Locked layers, SOLID hatches and 3D polylines are skipped

(vl-load-com)

(defun tv-hl-err (msg)
  (vla-EndUndoMark (vla-get-ActiveDocument (vlax-get-acad-object)))
  (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
  (princ))

(defun c:HSC (/ *error* old doc ss i o def v n skip)
  (setq old *error* *error* tv-hl-err doc (vla-get-ActiveDocument (vlax-get-acad-object)) n 0 skip 0)
  (setq ss (ssget "_I" '((0 . "HATCH"))))
  (sssetfirst nil nil)
  (if (null ss) (progn (princ "\nÇØÄ¡ ¼±ÅÃ: ") (setq ss (ssget "_:L" '((0 . "HATCH"))))))
  (if ss
    (progn
      (setq def (vla-get-PatternScale (vlax-ename->vla-object (ssname ss 0))))
      (setq v (getreal (strcat "\nÆÐÅÏ Ãàô <" (rtos def 2 2) ">: ")))
      (if (null v) (setq v def))
      (vla-StartUndoMark doc)
      (setq i 0)
      (repeat (sslength ss)
        (setq o (vlax-ename->vla-object (ssname ss i)) i (1+ i))
        ;; SOLID has no scale; locked layers (pre-selection) throw -> counted as skipped
        (if (and (/= (strcase (vla-get-PatternName o)) "SOLID")
                 (not (vl-catch-all-error-p (vl-catch-all-apply 'vla-put-PatternScale (list o v)))))
          (progn (vl-catch-all-apply 'vla-Evaluate (list o)) (setq n (1+ n)))
          (setq skip (1+ skip))))
      (vla-EndUndoMark doc)
      (princ (strcat "\n" (itoa n) " hatch(es) set to scale " (rtos v 2 2)
                     (if (> skip 0) (strcat ", " (itoa skip) " skipped (SOLID or locked)") "")))))
  (setq *error* old)
  (princ)
)

(defun c:PLW (/ *error* old doc ce pa ss i e v n)
  (setq old *error* doc (vla-get-ActiveDocument (vlax-get-acad-object))
        ce (getvar "CMDECHO") pa (getvar "PEDITACCEPT"))
  (defun *error* (msg)
    (setvar "CMDECHO" ce) (setvar "PEDITACCEPT" pa)
    (tv-hl-err msg)
    (setq *error* old))
  (if (null *TV-HL-WIDTH*) (setq *TV-HL-WIDTH* (* 5.0 (if (> (getvar "DIMSCALE") 0) (getvar "DIMSCALE") 1.0))))
  (princ "\n¼± ¼±ÅÃ: ")
  (if (setq ss (ssget "_:L" '((0 . "LINE,ARC,LWPOLYLINE,POLYLINE"))))
    (progn
      ;; 3D polylines and meshes take no width
      (setq i 0)
      (repeat (sslength ss)
        (setq e (ssname ss i) i (1+ i))
        (if (and (= (cdr (assoc 0 (entget e))) "POLYLINE") (/= 0 (logand 88 (cdr (assoc 70 (entget e))))))
          (setq ss (ssdel e ss) i (1- i))))
      (if (> (setq n (sslength ss)) 0)
        (progn
          (if (setq v (getdist (strcat "\n¼± µÎ²² <" (rtos *TV-HL-WIDTH* 2 1) ">: "))) (setq *TV-HL-WIDTH* v))
          (setvar "CMDECHO" 0)
          (setvar "PEDITACCEPT" 1)
          (vla-StartUndoMark doc)
          (command "_.PEDIT" "_M" ss "" "_W" *TV-HL-WIDTH* "")
          (vla-EndUndoMark doc)
          (princ (strcat "\n" (itoa n) " object(s) set to width " (rtos *TV-HL-WIDTH* 2 1)))))))
  (setvar "CMDECHO" ce) (setvar "PEDITACCEPT" pa)
  (setq *error* old)
  (princ)
)

(princ "\nTORVA Hatch Scale / Line Width: HSC / PLW | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----