;;; TORVA LISP - Continued Dimension (torva.kr/lisp.html)
;;; DMC : pick a linear dimension, then points -> continued dimensions in one row
;;; Extension line origins snap onto the row of the picked dimension, so points can be picked anywhere
;;; (e.g. on grid lines far above). Uses the picked dimension's style and layer

(vl-load-com)

;; point p (WCS) -> the row through p14 that runs along the dimension line
;; ag = extension line direction
(defun tv-dmc-foot (p p14 ag)
  (inters p (polar p ag 1.0) p14 (polar p14 (+ ag (/ pi 2)) 1.0) nil))

(defun c:DMC (/ *error* old osm lay ds sel ed p14 ag p n)
  (setq osm (getvar "OSMODE") lay (getvar "CLAYER") ds (getvar "DIMSTYLE") old *error*)
  (defun *error* (msg)
    (setvar "OSMODE" osm) (setvar "CLAYER" lay) (setvar "CMDECHO" 1)
    (setq *error* old)
    (if (not (wcmatch (strcase msg) "*CANCEL*,*QUIT*,*BREAK*")) (princ (strcat "\nError: " msg)))
    (princ))
  (setvar "CMDECHO" 0)
  ;; linear dimension only: 70 low bits 0 = rotated, 1 = aligned
  (while (and (setq sel (entsel "\n±âÁØ Ä¡¼ö ¼±ÅÃ: "))
              (not (and (= (cdr (assoc 0 (setq ed (entget (car sel))))) "DIMENSION")
                        (< (logand (cdr (assoc 70 ed)) 7) 2))))
    (princ "\nNot a linear dimension"))
  (if sel
    (progn
      (setq p14 (cdr (assoc 14 ed))
            ag (+ (/ pi 2) (if (= (logand (cdr (assoc 70 ed)) 7) 0)
                             (cdr (assoc 50 ed))
                             (angle (cdr (assoc 13 ed)) p14))))
      (setvar "CLAYER" (cdr (assoc 8 ed)))
      (command "_.-DIMSTYLE" "_R" (cdr (assoc 3 ed)))
      (setq n 0)
      (while (setq p (getpoint "\n´ÙÀ½ Á¡ (¿£ÅÍ = ³¡): "))
        (setq p (trans (tv-dmc-foot (trans p 1 0) p14 ag) 0 1))
        (setvar "OSMODE" 0)
        (if (= n 0) (command "_.DIMCONTINUE" "_S" sel p) (command p))
        (setvar "OSMODE" osm)
        (setq n (1+ n)))
      (while (> (getvar "CMDACTIVE") 0) (command ""))
      (if (/= ds (cdr (assoc 3 ed))) (command "_.-DIMSTYLE" "_R" ds))
      (princ (strcat "\n" (itoa n) " dimensions added"))))
  (setvar "OSMODE" osm) (setvar "CLAYER" lay) (setvar "CMDECHO" 1)
  (setq *error* old)
  (princ)
)

(princ "\nTORVA Continued Dimension: DMC | torva.kr")
(princ)

;;; ---- TVKEY: change a shortcut - shared by every TORVA LISP (torva.kr/lisp.html) ----
;;; TVKEY -> command -> new shortcut. The original command keeps working
;;; Shortcuts are saved on this PC as TORVA-KEYS and restored whenever a TORVA LISP loads
;;; (Every TORVA LISP carries this block; loading several just redefines the same functions)

;; "A1=PY;B2=CN;" -> (("A1" . "PY") ("B2" . "CN"))
(defun tv-key-list (/ s i out)
  (setq s (cond ((getenv "TORVA-KEYS")) ("")) out nil)
  (while (setq i (vl-string-search ";" s))
    (setq out (cons (substr s 1 i) out) s (substr s (+ i 2))))
  (if (/= s "") (setq out (cons s out)))
  (vl-remove nil
    (mapcar '(lambda (x / j) (if (setq j (vl-string-search "=" x)) (cons (substr x 1 j) (substr x (+ j 2)))))
            (reverse out))))

(defun tv-key-save (lst)
  (setenv "TORVA-KEYS" (apply 'strcat (mapcar '(lambda (p) (strcat (car p) "=" (cdr p) ";")) lst))))

;; is cmd a loaded LISP command
(defun tv-key-cmd-p (cmd)
  (member (type (eval (read (strcat "C:" cmd)))) '(SUBR USUBR EXRXSUBR)))

(defun tv-key-def (key cmd)
  (eval (list 'defun (read (strcat "C:" key)) '() (list (read (strcat "C:" cmd))) '(princ))))

;; is key an alias in acad.pgp ("L,   *LINE")
(defun tv-key-pgp-p (key / f h l hit)
  (if (setq f (findfile "acad.pgp"))
    (progn
      (setq h (open f "r"))
      (while (and (not hit) (setq l (read-line h)))
        (if (and (not (wcmatch l ";*")) (wcmatch (strcase l) (strcat key ",*"))) (setq hit T)))
      (close h)))
  hit)

;; reason the key cannot be used, nil if fine
(defun tv-key-bad (key lst)
  (cond
    ((not (vl-every '(lambda (c) (or (<= 48 c 57) (<= 65 c 90))) (vl-string->list key))) "¿µ¹®¡¤¼ýÀÚ¸¸")
    ((getcname key) "AutoCAD ¸í·É À̸§")
    ((tv-key-pgp-p key) "acad.pgp º°Äª°ú °°À½")
    ((and (tv-key-cmd-p key) (not (assoc key lst))) "ÀÌ¹Ì ÀÖ´Â ¸®½À ¸í·É")))

;; "My shortcuts" lines at the end of the file: (tv-my-key "A1" "BN"). Bad key -> reason only
(defun tv-my-key (key cmd / why)
  (setq key (strcase key) cmd (strcase cmd))
  (cond ((not (tv-key-cmd-p cmd)))
        ((setq why (tv-key-bad key (list (cons key cmd)))) (princ (strcat "\nShortcut " key ": " why)))
        (T (tv-key-def key cmd))))

(defun c:TVKEY (/ cmd key lst why)
  (setq lst (tv-key-list)
        cmd (strcase (getstring "\n´ÜÃàÅ°¸¦ ºÙÀÏ ¸í·É [¸ñ·Ï(?)]: ")))
  (cond
    ((= cmd ""))
    ((= cmd "?")
     (if lst
       (foreach p lst (princ (strcat "\n  " (car p) " = " (cdr p))))
       (princ "\nNo shortcuts set")))
    ((not (tv-key-cmd-p cmd)) (princ (strcat "\n" cmd " is not a loaded LISP command")))
    (T
     (setq key (strcase (getstring (strcat "\n" cmd " ÀÇ »õ ´ÜÃàÅ° [Áö¿ì±â(-)]: "))))
     (cond
       ((= key ""))
       ((= key "-")
        (foreach p lst
          (if (= (cdr p) cmd) (set (read (strcat "C:" (car p))) nil)))
        (tv-key-save (vl-remove-if '(lambda (p) (= (cdr p) cmd)) lst))
        (princ (strcat "\nShortcut for " cmd " removed")))
       ((= key cmd))
       ((setq why (tv-key-bad key lst)) (princ (strcat "\n" key ": " why)))
       (T
        (tv-key-save (cons (cons key cmd) (vl-remove-if '(lambda (p) (= (car p) key)) lst)))
        (tv-key-def key cmd)
        (princ (strcat "\n" key " now runs " cmd))))))
  (princ))

;; on load: restore saved shortcuts whose command is loaded
(foreach p (tv-key-list)
  (if (tv-key-cmd-p (cdr p)) (tv-key-def (car p) (cdr p))))
(princ "\nTVKEY: change a shortcut | torva.kr")
(princ)

;;; ---- My shortcuts: lines set at torva.kr download land below. Edit or add lines to change them ----